Fonction local-name() |
Renvoie l'élément local du premier nœud de l'ensemble de nœuds de l'argument.
Entrées
Un ensemble de nœuds. Si l'ensemble de nœuds est vide, la fonction renvoie une chaîne vide. Si l'ensemble de nœuds est omis, la fonction utilise un ensemble de nœuds ayant pour seul membre le nœud de contexte.
Sortie
Une chaîne correspondant au nom local du premier élément de l'ensemble de nœuds de l'argument. Si l'ensemble de nœuds est vide, la fonction local-name() renvoie une chaîne vide.
Définie dans
XPath section 4.1, Fonctions Ensemble de nœuds.
Exemple
La feuille de style suivante utilise la fonction document() pour traiter l'ensemble de ses nœuds. Elle appelle ensuite la fonction local-name() pour chaque nœud.
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns:months="Lookup table for month names">

      <months:name sequence="12">December</months:name>
      <months:name sequence="01">January</months:name>
      <months:name sequence="02">February</months:name>
      <months:name sequence="03">March</months:name>
      <months:name sequence="04">April</months:name>
      <months:name sequence="05">May</months:name>
      <months:name sequence="06">June</months:name>
      <months:name sequence="07">July</months:name>
      <months:name sequence="08">August</months:name>
      <months:name sequence="09">September</months:name>
      <months:name sequence="10">October</months:name>
      <months:name sequence="11">November</months:name>

      <xsl:output method="text"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:text>A test of the local-name() function:</xsl:text>

        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="document('')//*">
          <xsl:text>local-name: </xsl:text>
          <xsl:value-of select="local-name()"/>
          <xsl:value-of select="$newline"/>
        </xsl:for-each>
      </xsl:template>

    </xsl:stylesheet>
La feuille de style génère les résultats suivants :
    A test of the local-name() function:

    local-name: stylesheet
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: output
    local-name: variable
    local-name: text
    local-name: template
    local-name: value-of
    local-name: text
    local-name: value-of
    local-name: value-of
    local-name: for-each
    local-name: text
    local-name: value-of
    local-name: value-of