<xsl:strip-space> |
Définit les éléments du document source desquels il faut supprimer un espace blanc.
Catégorie
Elément de niveau supérieur
Attributs obligatoires
elements Contient une liste des éléments du document source séparés par des espaces pour lesquels les espaces blancs inutiles doivent être supprimés. Par espace blanc inutile, on entend généralement des nœuds de texte ne contenant rien d'autre qu'un espace blanc ; les espaces blancs apparaissant à l'intérieur et autour d'un texte sont conservés.
Attributs facultatifs
Aucun.
Contenu
Aucun. <xsl:strip-space> est un élément vide.
Apparaît dans
L'élément <xsl:strip-space> est un élément de niveau supérieur qui ne peut apparaître que comme un enfant de l'élément <xsl:stylesheet> .
Défini dans
XSLT section 3.4, Extraction des espaces blancs.
Exemple
La feuille de style suivante illustre le fonctionnement de l'élément <xsl:strip-space> :
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="text"/>
      <xsl:strip-space elements="listing"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:value-of select="/code-sample/title"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="/code-sample/listing">
          <xsl:value-of select="."/>
        </xsl:for-each>
      </xsl:template>

    </xsl:stylesheet>
La feuille de style est utilisée pour traiter le document suivant :
    <?xml version="1.0"?>
    <code-sample>
      <title>Conditional variable initialization</title>
      <listing>
      <type>int</type> <variable>y</variable> = <constant>23</constant>;
      <type>int</type> <variable>x</variable>;

        <keyword>if</keyword> (<variable>y</variable> > <constant>10</constant>)
        <variable>x</variable> = <constant>5</constant>;
      <keyword>else</keyword>
        <keyword>if</keyword> (<variable>y</variable> > <constant>5</constant>)
          <variable>x</variable> = <constant>3</constant>;
      <keyword>else</keyword>
        <variable>x</variable> = <constant>1</constant>;
      </listing>
    </code-sample>
Les résultats sont les suivants :
    Conditional variable initialization
    inty = 23;
      intx;
        if (y > 10)
        x = 5;
      elseif (y > 5)
          x = 3;
      elsex = 1;
Tous les espaces blancs supplémentaires de l'élément <listing> ont été supprimés. Cela inclut l'espace entre les différents éléments contenus dans <listing>, comme par exemple <keyword>, <constant> et <variable>. Vous pouvez comparer cet exemple à celui utilisé pour l'élément <preserve-space>.